*********************************************************
*
* Table B5: General itinerary plotted: Estimation results
*
*********************************************************

global program "TableB5"

cap log close
cap log using "$log_files/log_$program$today", replace

clear all
set mem 2g
set more off
set matsize 11000
set scheme s1color

***************************
***** 1. PREPARE DATA *****
***************************

// Get data

use "$data/Data_County", clear

// Controls definition

global geog 		"railroad_dens ldist_capital ldist_largest county_lat county_lon" 
global demo 		"urban_dum perc_pop_dstr lpop_total perc_white perc_male21 perc_below21 perc_native perc_literate newsp_circ_elig" 
global demo_cont	"perc_pop_dstr lpop_total perc_white perc_male21 perc_below21 perc_native perc_literate newsp_circ_elig" 
global econ 		"perc_farm perc_manuf dlog_avbasket ldist_silver ldist_gold" 
global econ_cont	"perc_farm perc_manuf dlog_avbasket ldist_silver ldist_gold" 
global econ_p 		"perc_farm perc_manuf log_avbasket ldist_silver ldist_gold" 
global vote 		"lag_margin_pres_ttl" 			
global demo_add		"urban_dum lpop_total larea perc_white perc_below21 perc_native perc_literate newsp_circ_elig pop_male2144 pop_male4564 pop_male6599 perc_catholic perc_black"

// Indicator for state variation

bysort state year: egen state_route=max(planned_route)

****************************
***** 2. TABLE RESULTS *****
****************************

// Plotted or speech (Column 1)

g sample=1*(planned_route==1 | speech==1)

reghdfe dempop_pres_ttl speech lag_dem_pres_ttl lag_pop_pres_ttl	$demo $geog $econ if year==1896 & sample==1 & railroad_dum==1 & state_route==1, cluster(district) a(state) // keepsing
estimates store itinerary_planspeech
qui sum dempop_pres_ttl if e(sample)
scalar mean_y=r(mean)
estadd scalar mean_y
qui sum speech if e(sample)
scalar mean_x=r(mean)
estadd scalar mean_x

// Excluding exact mentions (Column 2)

reghdfe dempop_pres_ttl speech lag_dem_pres_ttl lag_pop_pres_ttl	$demo $geog $econ if year==1896 & sample==1 & railroad_dum==1 & planned_location!=1 & state_route==1, cluster(district) a(state) // keepsing
estimates store itinerary_nomention
qui sum dempop_pres_ttl if e(sample)
scalar mean_y=r(mean)
estadd scalar mean_y
qui sum speech if e(sample)
scalar mean_x=r(mean)
estadd scalar mean_x

// Excluding plotted with speech (Column 3)

replace sample=0 if planned_route==1 & speech==1

reghdfe dempop_pres_ttl speech lag_dem_pres_ttl lag_pop_pres_ttl	$demo $geog $econ if year==1896 & sample==1 & railroad_dum==1 & state_route==1, cluster(district) a(state) // keepsing
estimates store itinerary_excludespeech
qui sum dempop_pres_ttl if e(sample)
scalar mean_y=r(mean)
estadd scalar mean_y
qui sum speech if e(sample)
scalar mean_x=r(mean)
estadd scalar mean_x

// Excluding speech counties (Column 4)

cap drop sample
g sample=1*(speech==0)

reghdfe dempop_pres_ttl planned_route lag_dem_pres_ttl lag_pop_pres_ttl	$demo $geog $econ if year==1896 & sample==1 & railroad_dum==1 & state_route==1, cluster(district) a(state) // keepsing
estimates store itinerary_nospeech
qui sum dempop_pres_ttl if e(sample)
scalar mean_y=r(mean)
estadd scalar mean_y
qui sum planned_route if e(sample)
scalar mean_x=r(mean)
estadd scalar mean_x

// Excluding route performed (Column 5)

cap drop sample
g sample=1*(performed_route==0)

reghdfe dempop_pres_ttl planned_route lag_dem_pres_ttl lag_pop_pres_ttl	$demo $geog $econ if year==1896 & sample==1 & railroad_dum==1 & state_route==1, cluster(district) a(state) // keepsing
estimates store itinerary_noroute
qui sum dempop_pres_ttl if e(sample)
scalar mean_y=r(mean)
estadd scalar mean_y
qui sum planned_route if e(sample)
scalar mean_x=r(mean)
estadd scalar mean_x

***************************
***** 3. EXPORT TABLE *****
***************************

// Fixed effects

estfe . itinerary_*, labels(state "State FE")
return list

// Table 

estout itinerary_planspeech itinerary_nomention itinerary_excludespeech itinerary_nospeech itinerary_noroute ///  
	using "$tables/$program.tex", replace style(tex) type label ///
	cells(b(fmt(%9.3f) star) se(par fmt(%9.3f)))  ///
	stats(mean_y mean_x N N_clust r2_a, lab("Mean dep. variable" "Mean exp. variable" "Observations" "Clusters" "Adjusted $ R^2 $") fmt(2 2 %9.0fc 0 2)) ///
	collabels(none) ///
	mlabels(, span none prefix(\multicolumn{@span}{c}{) suffix(})) ///
	msign(--) starlevels(* .1 ** .05 *** .01) ///
	keep(speech planned_route lag_dem_pres_ttl lag_pop_pres_ttl) /// 
	order(speech planned_route lag_dem_pres_ttl lag_pop_pres_ttl ) /// 
	varlabels(speech "Speech (binary)" planned_route "[0.5em] Plotted itinerary (binary)" lag_dem_pres_ttl "[0.5em] Lag Democratic (\%)" lag_pop_pres_ttl "[0.5em] Lag Populist (\%)") ///
	title(General itinerary plotted: Estimation results) ///
	indicate("\\ Demographic controls = lpop_total" ///	
	"Geographic controls = county_lat" ///	
	"Economic controls = dlog_avbasket" ///	
	"State FE = 0.state" ///	
	, labels(Yes )) ///
	prehead("\begin{table}[h!]" ///
	"\begin{center}" ///
	"\begin{threeparttable}" ///
	"\begin{scriptsize}" ///
	"\caption{@title}\label{$program}" ///
	"\begin{tabular*}{\columnwidth}{@{\extracolsep{\stretch{1}}}l*{@M}{c}@{}}" ///
	"\hline" "\hline" ///
	"		&\multicolumn{1}{c}{(1)} 			&\multicolumn{1}{c}{(2)} 				&\multicolumn{1}{c}{(3)} 			&\multicolumn{1}{c}{(4)} 		&\multicolumn{1}{c}{(5)}\\" ///
	"\multicolumn{1}{l}{\textit{Dep. Variable}}		&\multicolumn{1}{c}{Plotted}	&\multicolumn{1}{c}{Excl. exact}	&\multicolumn{1}{c}{Excl. plotted}		&\multicolumn{1}{c}{Excl. speech} 	&\multicolumn{1}{c}{Excl. route}\\" ///
	"\multicolumn{1}{l}{\textit{Democratic vote (\%) in 1896}}	&\multicolumn{1}{c}{or speech}	&\multicolumn{1}{c}{mentions}			&\multicolumn{1}{c}{with speech}		&\multicolumn{1}{c}{counties}		&\multicolumn{1}{c}{performed}\\" ///
	"\hline") ///
	posthead("\\") ///
	prefoot("\hline") ///
	postfoot("\hline" "\hline" ///
	"\end{tabular*}" /// 
	"\end{scriptsize}" ///
	"\begin{tablenotes}[normal,flushleft]" ///
	"\begin{scriptsize}" ///
	"\item \emph{Notes}: OLS regressions. The unit of observation is a county. " ///
	"Demographic controls: Urban (binary), District population (\%),  Log population, White (\%), Male above 21 (\%), Native (\%). " ///
	"Geographic controls: Railroad density (km per sq. km), Distance to state capital (log), Distance to state largest city (log), Latitude, Longitude. " ///
	"Economic controls: Farmers (\%), Manufacture workers (\%)." ///
	"All regressions include State fixed-effects. " ///
	"Standard errors clustered at the Congressional district level in parentheses. Standard errors adjusted for spatial correlation in square brackets." /// 
	"* significant at 10\%; ** at 5\%; *** at 1\%. " ///	
	"\end{scriptsize}" ///
	"\end{tablenotes}" ///
	"\end{threeparttable} " ///
	"\end{center}" ///
	"\end{table}") //	

cap log close
